Object that can be treated as both a string and number
class Cool is Any { }
Cool, also known as the Convenient OO Loop, is a base class employed by a number of built-in classes whose instances can be meaningfully coerced to a string and a number. For example, an Array can be used in mathematical operations, where its numerical representation is the number of elements it contains. At the same time, it can be concatenated to a string, where its stringy representation is all of its elements joined by a space. Because Array is Cool, the appropriate coercion happens automatically.
Methods in Cool coerce the invocant to a more specific type, and then call the same method on that type. For example both Int and Str inherit from Cool, and calling method substr on an Int converts the integer to Str first.
123.substr(1, 1); # '2', same as 123.Str.substr(1, 1)
Several built-in types inherit from Cool. See the Type Graph below for a snapshot.
The following table summarizes the methods that Cool provides, and what type they coerce to:
| method | coercion type |
|---|---|
| abs | Numeric |
| conj | Numeric |
| sqrt | Numeric |
| sign | Real |
| rand | Numeric |
| sin | Numeric |
| asin | Numeric |
| cos | Numeric |
| acos | Numeric |
| tan | Numeric |
| tanh | Numeric |
| atan | Numeric |
| atan2 | Numeric |
| atanh | Numeric |
| sec | Numeric |
| asec | Numeric |
| cosec | Numeric |
| acosec | Numeric |
| cotan | Numeric |
| cotanh | Numeric |
| acotan | Numeric |
| sinh | Numeric |
| asinh | Numeric |
| cosh | Numeric |
| acosh | Numeric |
| sech | Numeric |
| asech | Numeric |
| cosech | Numeric |
| acosech | Numeric |
| acotanh | Numeric |
| cis | Numeric |
| log | Numeric |
| exp | Numeric |
| roots | Numeric |
| log10 | Numeric |
| log2 | Numeric |
| unpolar | Numeric |
| round | Numeric |
| floor | Numeric |
| ceiling | Numeric |
| truncate | Numeric |
| chr | Int |
| ord | Str |
| chars | Str |
| fmt | Str |
| uniname | Str |
| uninames | Seq |
| unival | Str |
| univals | Str |
| uniprop | Str |
| unimatch | Str |
| uc | Str |
| lc | Str |
| fc | Str |
| tc | Str |
| tclc | Str |
| flip | Str |
| trans | Str |
| contains | Str |
| index | Str |
| rindex | Str |
| ords | Str |
| split | Str |
| match | Str |
| comb | Str |
| subst | Str |
| sprintf | Str |
| printf | Str |
| samecase | Str |
| trim | Str |
| trim-leading | Str |
| trim-trailing | Str |
| EVAL | Str |
| chomp | Str |
| chop | Str |
| codes | Str |
| Complex | Numeric |
| FatRat | Numeric |
| Int | Numeric |
| Num | Numeric |
| Rat | Numeric |
| Real | Numeric |
| UInt | Numeric |
sub abs(Numeric() $x)
method abs()
Coerces the invocant (or in the sub form, the argument) to Numeric and returns the absolute value (that is, a non-negative number).
say (-2).abs; # OUTPUT: «2»
say abs "6+8i"; # OUTPUT: «10»
method conj()
Coerces the invocant to Numeric and returns the Complex conjugate (that is, the number with the sign of the imaginary part negated).
say "1+2i".conj; # OUTPUT: «1-2i»
method EVAL(*%_)
It calls the subroutine form with the invocant as the first argument, $code, passing along named args, if any.
sub sqrt(Numeric(Cool) $x)
method sqrt()
Coerces the invocant to Numeric (or in the sub form, the argument) and returns the square root, that is, a number that, when multiplied with itself, produces the original number.
say 4.sqrt; # OUTPUT: «2»
say sqrt(2); # OUTPUT: «1.4142135623731»
Returns NaN for negative arguments. As of 6.e language version (early implementation exists in Rakudo compiler 2023.02+), will return a Complex value for negative arguments.
say sqrt(-1); # OUTPUT: «0+1i»
method sign()
Coerces the invocant to Real and returns its sign, that is, 0 if the number is 0, 1 for positive and -1 for negative values.
say 6.sign; # OUTPUT: «1»
say (-6).sign; # OUTPUT: «-1»
say "0".sign; # OUTPUT: «0»
method rand()
Coerces the invocant to Num and returns a pseudo-random value between zero and the number.
say 1e5.rand; # OUTPUT: «33128.495184283»
sub sin(Numeric(Cool))
method sin()
Coerces the invocant (or in the sub form, the argument) to Numeric, interprets it as radians, returns its sine.
say sin(0); # OUTPUT: «0»
say sin(pi/4); # OUTPUT: «0.707106781186547»
say sin(pi/2); # OUTPUT: «1»
Note that Raku is no computer algebra system, so sin(pi) typically does not produce an exact 0, but rather a very small Num.
sub asin(Numeric(Cool))
method asin()
Coerces the invocant (or in the sub form, the argument) to Numeric, and returns its arc-sine in radians.
say 0.1.asin; # OUTPUT: «0.10016742116156»
say asin(0.1); # OUTPUT: «0.10016742116156»
sub cos(Numeric(Cool))
method cos()
Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its cosine.
say 0.cos; # OUTPUT: «1»
say pi.cos; # OUTPUT: «-1»
say cos(pi/2); # OUTPUT: «6.12323399573677e-17»
sub acos(Numeric(Cool))
method acos()
Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-cosine in radians.
say 1.acos; # OUTPUT: «0»
say acos(-1); # OUTPUT: «3.14159265358979»
sub tan(Numeric(Cool))
method tan()
Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its tangent.
say tan(3); # OUTPUT: «-0.142546543074278»
say 3.tan; # OUTPUT: «-0.142546543074278»
sub atan(Numeric(Cool))
method atan()
Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-tangent in radians.
say atan(3); # OUTPUT: «1.24904577239825»
say 3.atan; # OUTPUT: «1.24904577239825»
sub atan2($y, $x = 1e0)
method atan2($x = 1e0)
The sub should usually be written with two arguments for clarity as it is seen in other languages and in mathematical texts, but the single-argument form is available; its result will always match that of atan.
say atan2 3, 1; # OUTPUT: «1.2490457723982544»
say atan2 3; # OUTPUT: «1.2490457723982544»
say atan2 ⅔, ⅓; # OUTPUT: «1.1071487177940904»
The method coerces self and its single argument to Numeric, using them to compute the two-argument arc-tangent in radians.
say 3.atan2; # OUTPUT: «1.24904577239825»
say ⅔.atan2(⅓); # OUTPUT: «1.1071487177940904»
The $x argument in either the method or the sub defaults to 1 so, in both single-argument cases, the function will return the angle θ in radians between the x-axis and a vector that goes from the origin to the point (3, 1).
sub sec(Numeric(Cool))
method sec()
Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its secant, that is, the reciprocal of its cosine.
say 45.sec; # OUTPUT: «1.90359440740442»
say sec(45); # OUTPUT: «1.90359440740442»
sub asec(Numeric(Cool))
method asec()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-secant in radians.
say 1.asec; # OUTPUT: «0»
say sqrt(2).asec; # OUTPUT: «0.785398163397448»
sub cosec(Numeric(Cool))
method cosec()
Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cosecant, that is, the reciprocal of its sine.
say 0.45.cosec; # OUTPUT: «2.29903273150897»
say cosec(0.45); # OUTPUT: «2.29903273150897»
sub acosec(Numeric(Cool))
method acosec()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cosecant in radians.
say 45.acosec; # OUTPUT: «0.0222240516182672»
say acosec(45) # OUTPUT: «0.0222240516182672»
sub cotan(Numeric(Cool))
method cotan()
Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cotangent, that is, the reciprocal of its tangent.
say 45.cotan; # OUTPUT: «0.617369623783555»
say cotan(45); # OUTPUT: «0.617369623783555»
sub acotan(Numeric(Cool))
method acotan()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cotangent in radians.
say 45.acotan; # OUTPUT: «0.0222185653267191»
say acotan(45) # OUTPUT: «0.0222185653267191»
sub sinh(Numeric(Cool))
method sinh()
Coerces the invocant (or in method form, its argument) to Numeric, and returns its Sine hyperbolicus.
say 1.sinh; # OUTPUT: «1.1752011936438»
say sinh(1); # OUTPUT: «1.1752011936438»
sub asinh(Numeric(Cool))
method asinh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Sine hyperbolicus.
say 1.asinh; # OUTPUT: «0.881373587019543»
say asinh(1); # OUTPUT: «0.881373587019543»
sub cosh(Numeric(Cool))
method cosh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Cosine hyperbolicus.
say cosh(0.5); # OUTPUT: «1.12762596520638»
sub acosh(Numeric(Cool))
method acosh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Cosine hyperbolicus.
say acosh(45); # OUTPUT: «4.4996861906715»
sub tanh(Numeric(Cool))
method tanh()
Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians and returns its Tangent hyperbolicus.
say tanh(0.5); # OUTPUT: «0.46211715726001»
say tanh(atanh(0.5)); # OUTPUT: «0.5»
sub atanh(Numeric(Cool))
method atanh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse tangent hyperbolicus.
say atanh(0.5); # OUTPUT: «0.549306144334055»
sub sech(Numeric(Cool))
method sech()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Secant hyperbolicus.
say 0.sech; # OUTPUT: «1»
sub asech(Numeric(Cool))
method asech()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic secant.
say 0.8.asech; # OUTPUT: «0.693147180559945»
sub cosech(Numeric(Cool))
method cosech()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cosecant.
say cosech(pi/2); # OUTPUT: «0.434537208094696»
sub acosech(Numeric(Cool))
method acosech()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cosecant.
say acosech(4.5); # OUTPUT: «0.220432720979802»
sub cotanh(Numeric(Cool))
method cotanh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cotangent.
say cotanh(pi); # OUTPUT: «1.00374187319732»
sub acotanh(Numeric(Cool))
method acotanh()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cotangent.
say acotanh(2.5); # OUTPUT: «0.423648930193602»
sub cis(Numeric(Cool))
method cis()
Coerces the invocant (or in sub form, its argument) to Numeric, and returns cos(argument) + i*sin(argument).
say cis(pi/4); # OUTPUT: «0.707106781186548+0.707106781186547i»
multi log(Numeric(Cool) $number, Numeric(Cool) $base?)
multi method log(Cool:D: Cool:D $base?)
Coerces the arguments (including the invocant in the method form) to Numeric, and returns its Logarithm to base $base, or to base e (Euler's Number) if no base was supplied (Natural logarithm). Throws an exception if $base is 1.
say (e*e).log; # OUTPUT: «2»
Returns NaN for negative arguments. As of 6.e language version (early implementation exists in Rakudo compiler 2023.02+), will return a Complex value for negative arguments.
multi method log10()
multi log10(Numeric $x)
multi log10(Cool $x)
Coerces the invocant (or in the sub form, the argument) to Numeric (or uses it directly if it's already in that form), and returns its Logarithm in base 10, that is, a number that approximately produces the original number when 10 is raised to its power. Returns -Inf for 0.
say log10(1001); # OUTPUT: «3.00043407747932»
Returns NaN for negative arguments. As of 6.e language version (early implementation exists in Rakudo compiler 2023.02+), will return a Complex value for negative arguments.
multi method log2()
multi log2(Numeric $x)
multi log2(Cool $x)
Coerces the invocant to Numeric, and returns its Logarithm in base 2, that is, a number that approximately (due to computer precision limitations) produces the original number when 2 is raised to its power. Returns -Inf for 0.
say log2(5); # OUTPUT: «2.321928094887362»
say "4".log2; # OUTPUT: «2»
say 4.log2; # OUTPUT: «2»
Returns NaN for negative arguments. As of 6.e language version (early implementation exists in Rakudo compiler 2023.02+), will return a Complex value for negative arguments.
multi exp(Cool:D $pow, Cool:D $base?)
multi method exp(Cool:D: Cool:D $base?)
Coerces the arguments (including the invocant in the method from) to Numeric, and returns $base raised to the power of the first number. If no $base is supplied, e (Euler's Number) is used.
say 0.exp; # OUTPUT: «1»
say 1.exp; # OUTPUT: «2.71828182845905»
say 10.exp; # OUTPUT: «22026.4657948067»
method unpolar(Numeric(Cool))
Coerces the arguments (including the invocant in the method form) to Numeric, and returns a complex number from the given polar coordinates. The invocant (or the first argument in sub form) is the magnitude while the argument (i.e. the second argument in sub form) is the angle. The angle is assumed to be in radians.
say sqrt(2).unpolar(pi/4); # OUTPUT: «1+1i»
multi round(Numeric(Cool), $scale = 1)
multi method round(Cool:D: $scale = 1)
Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it to the unit of $scale. If $scale is 1, rounds to the nearest integer; an arbitrary scale will result in the closest multiple of that number.
say 1.7.round; # OUTPUT: «2»
say 1.07.round(0.1); # OUTPUT: «1.1»
say 21.round(10); # OUTPUT: «20»
say round(1000, 23.01) # OUTPUT: «989.43»
Always rounds up if the number is at mid-point:
say (−.5 ).round; # OUTPUT: «0»
say ( .5 ).round; # OUTPUT: «1»
say (−.55).round(.1); # OUTPUT: «-0.5»
say ( .55).round(.1); # OUTPUT: «0.6»
Pay attention to types when using this method, as ending up with the wrong type may affect the precision you seek to achieve. For Real types, the type of the result is the type of the argument (Complex argument gets coerced to Real, ending up a Num). If rounding a Complex, the result is Complex as well, regardless of the type of the argument.
9930972392403501.round(1) .raku.say; # OUTPUT: «9930972392403501»
9930972392403501.round(1e0) .raku.say; # OUTPUT: «9.9309723924035e+15»
9930972392403501.round(1e0).Int.raku.say; # OUTPUT: «9930972392403500»
multi floor(Numeric(Cool))
multi method floor
Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it downwards to the nearest integer.
say "1.99".floor; # OUTPUT: «1»
say "-1.9".floor; # OUTPUT: «-2»
say 0.floor; # OUTPUT: «0»
method fmt($format = '%s')
Uses $format to return a formatted representation of the invocant; equivalent to calling sprintf with $format as format and the invocant as the second argument. The $format will be coerced to Stringy and defaults to '%s'.
For more information about formats strings, see sprintf.
say 11.fmt('This Int equals %03d'); # OUTPUT: «This Int equals 011»
say '16'.fmt('Hexadecimal %x'); # OUTPUT: «Hexadecimal 10»
multi ceiling(Numeric(Cool))
multi method ceiling
Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it upwards to the nearest integer.
say "1".ceiling; # OUTPUT: «1»
say "-0.9".ceiling; # OUTPUT: «0»
say "42.1".ceiling; # OUTPUT: «43»
multi truncate(Numeric(Cool))
multi method truncate()
Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it towards zero.
say 1.2.truncate; # OUTPUT: «1»
say truncate -1.2; # OUTPUT: «-1»
sub ord(Str(Cool))
method ord()
Coerces the invocant (or in sub form, its argument) to Str, and returns the Unicode code point number of the first code point.
say 'a'.ord; # OUTPUT: «97»
The inverse operation is chr.
Mnemonic: returns an ordinal number
method path(Cool:D: --> IO::Path:D)
DEPRECATED. It's been deprecated as of the 6.d version. Will be removed in the next ones.
Stringifies the invocant and converts it to IO::Path object. Use the .IO method instead.
sub chr(Int(Cool))
method chr()
Coerces the invocant (or in sub form, its argument) to Int, interprets it as a Unicode code points, and returns a Str made of that code point.
say '65'.chr; # OUTPUT: «A»
The inverse operation is ord.
Mnemonic: turns an integer into a character.
multi chars(Cool $x)
multi chars(Str:D $x)
multi chars(str $x --> int)
method chars(--> Int:D)
Coerces the invocant (or in sub form, its argument) to Str, and returns the number of characters in the string. Please note that on the JVM, you currently get codepoints instead of graphemes.
say 'møp'.chars; # OUTPUT: «3»
say 'ã̷̠̬̊'.chars; # OUTPUT: «1»
say '👨👩👧👦🏿'.chars; # OUTPUT: «1»
If the string is native, the number of chars will be also returned as a native int.
Graphemes are user visible characters. That is, this is what the user thinks of as a “character”.
Graphemes can contain more than one codepoint. Typically the number of graphemes and codepoints differs when Prepend or Extend characters are involved (also known as Combining characters), but there are many other cases when this may happen. Another example is \c[ZWJ] (Zero-width joiner).
You can check Grapheme_Cluster_Break property of a character in order to see how it is going to behave:
say ‘ã̷̠̬̊’.uniprops(‘Grapheme_Cluster_Break’); # OUTPUT: «(Other Extend Extend Extend Extend)»
say ‘👨👩👧👦🏿’.uniprops(‘Grapheme_Cluster_Break’); # OUTPUT: «(E_Base_GAZ ZWJ E_Base_GAZ ZWJ E_Base_GAZ ZWJ E_Base_GAZ E_Modifier)»
You can read more about graphemes in the Unicode Standard, which Raku tightly follows, using a method called NFG, normal form graphemes for efficiently representing them.
sub codes(Str(Cool))
method codes()
Coerces the invocant (or in sub form, its argument) to Str, and returns the number of Unicode code points.
say 'møp'.codes; # OUTPUT: «3»
The same result will be obtained with
say +'møp'.ords; # OUTPUT: «3»
ords first obtains the actual codepoints, so there might be a difference in speed.
sub flip(Cool $s --> Str:D)
method flip()
Coerces the invocant (or in sub form, its argument) to Str, and returns a reversed version.
say 421.flip; # OUTPUT: «124»
sub trim(Str(Cool))
method trim()
Coerces the invocant (or in sub form, its argument) to Str, and returns the string with both leading and trailing whitespace stripped.
my $stripped = ' abc '.trim;
say "<$stripped>"; # OUTPUT: «<abc>»
sub trim-leading(Str(Cool))
method trim-leading()
Coerces the invocant (or in sub form, its argument) to Str, and returns the string with leading whitespace stripped.
my $stripped = ' abc '.trim-leading;
say "<$stripped>"; # OUTPUT: «<abc >»
sub trim-trailing(Str(Cool))
method trim-trailing()
Coerces the invocant (or in sub form, its argument) to Str, and returns the string with trailing whitespace stripped.
my $stripped = ' abc '.trim-trailing;
say "<$stripped>"; # OUTPUT: «< abc>»
sub lc(Str(Cool))
method lc()
Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to lowercase.
say "ABC".lc; # OUTPUT: «abc»
sub uc(Str(Cool))
method uc()
Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to uppercase (capital letters).
say "Abc".uc; # OUTPUT: «ABC»
sub fc(Str(Cool))
method fc()
Coerces the invocant (or in sub form, its argument) to Str, and returns the result a Unicode "case fold" operation suitable for doing caseless string comparisons. (In general, the returned string is unlikely to be useful for any purpose other than comparison.)
say "groß".fc; # OUTPUT: «gross»
sub tc(Str(Cool))
method tc()
Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to titlecase (or where not available, uppercase).
say "abC".tc; # OUTPUT: «AbC»
sub tclc(Str(Cool))
method tclc()
Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to titlecase (or where not available, uppercase), and the rest of the string case-folded to lowercase.
say 'abC'.tclc; # OUTPUT: «Abc»
sub wordcase(Str(Cool) $input, :&filter = &tclc, Mu :$where = True)
method wordcase(:&filter = &tclc, Mu :$where = True)
Coerces the invocant (or in sub form, the first argument) to Str, and filters each word that smartmatches against $where through the &filter. With the default filter (first character to uppercase, rest to lowercase) and matcher (which accepts everything), this titlecases each word:
say "raku programming".wordcase; # OUTPUT: «Raku Programming»
With a matcher:
say "have fun working on raku".wordcase(:where({ .chars > 3 }));
# Have fun Working on Raku
With a customer filter too:
say "have fun working on raku".wordcase(:filter(&uc), :where({ .chars > 3 }));
# HAVE fun WORKING on RAKU
sub samecase(Cool $string, Cool $pattern)
method samecase(Cool:D: Cool $pattern)
Coerces the invocant (or in sub form, the first argument) to Str, and calls Str.samecase on it.
say "raKu".samecase("A_a_"); # OUTPUT: «Raku»
say "rAKU".samecase("Ab"); # OUTPUT: «Raku»
multi uniprop(Str:D, |c)
multi uniprop(Int:D $code)
multi uniprop(Int:D $code, Stringy:D $propname)
multi method uniprop(|c)
Returns the unicode property of the first character. If no property is specified returns the General Category. Returns a Bool for Boolean properties. A uniprops routine can be used to get the property for every character in a string.
say 'a'.uniprop; # OUTPUT: «Ll»
say '1'.uniprop; # OUTPUT: «Nd»
say 'a'.uniprop('Alphabetic'); # OUTPUT: «True»
say '1'.uniprop('Alphabetic'); # OUTPUT: «False»
sub uniprops(Str:D $str, Stringy:D $propname = "General_Category")
Interprets the invocant as a Str, and returns the unicode property for each character as a Seq. If no property is specified returns the General Category. Returns a Bool for Boolean properties. Similar to uniprop, but for each character in the passed string.
sub uniname(Str(Cool) --> Str)
method uniname(--> Str)
Interprets the invocant or first argument as a Str, and returns the Unicode codepoint name of the first codepoint of the first character. See uninames for a routine that works with multiple codepoints, and uniparse for the opposite direction.
# Camelia in Unicode
say ‘»ö«’.uniname;
# OUTPUT: «RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK»
say "Ḍ̇".uniname; # Note, doesn't show "COMBINING DOT ABOVE"
# OUTPUT: «LATIN CAPITAL LETTER D WITH DOT BELOW»
# Find the char with the longest Unicode name.
say (0..0x1FFFF).sort(*.uniname.chars)[*-1].chr.uniname;
# OUTPUT: «BOX DRAWINGS LIGHT DIAGONAL UPPER CENTRE TO MIDDLE RIGHT AND MIDDLE LEFT TO LOWER CENTRE»
Available as of the 2021.04 Rakudo compiler release.
sub uninames(Str:D)
method uninames()
Returns of a Seq of Unicode names for the all the codepoints in the Str provided.
say ‘»ö«’.uninames.raku;
# OUTPUT: «("RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK", "LATIN SMALL LETTER O WITH DIAERESIS", "LEFT-POINTING DOUBLE ANGLE QUOTATION MARK").Seq»
Note this example, which gets a Seq where each element is a Seq of all the codepoints in that character.
say "Ḍ̇'oh".comb>>.uninames.raku;
# OUTPUT: «(("LATIN CAPITAL LETTER D WITH DOT BELOW", "COMBINING DOT ABOVE").Seq, ("APOSTROPHE",).Seq, ("LATIN SMALL LETTER O",).Seq, ("LATIN SMALL LETTER H",).Seq)»
See uniname for the name of the first codepoint of the first character in the provided Str and uniparse for the opposite direction.
multi unimatch(Str:D $str, |c)
multi unimatch(Int:D $code, Stringy:D $pvalname, Stringy:D $propname = $pvalname)
Checks if the given integer codepoint or the first letter of the given string has a unicode property equal to the value you give. If you supply the Unicode property to be checked it will only return True if that property matches the given value.
say unimatch 'A', 'Latin'; # OUTPUT: «True»
say unimatch 'A', 'Latin', 'Script'; # OUTPUT: «True»
say unimatch 'A', 'Ll'; # OUTPUT: «False»
The last property corresponds to "lowercase letter", which explains why it returns false.
sub chop(Str(Cool))
method chop()
Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed.
say 'raku'.chop; # OUTPUT: «rak»
sub chomp(Str(Cool))
method chomp()
Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed, if it is a logical newline.
say 'ab'.chomp.chars; # OUTPUT: «2»
say "a\n".chomp.chars; # OUTPUT: «1»
sub substr(Str(Cool) $str, |c)
method substr(|c)
Coerces the invocant (or in the sub form, the first argument) to Str, and calls Str.substr with the arguments.
multi method substr-rw(|) is rw
multi substr-rw(|) is rw
Coerces the invocant (or in the sub form, the first argument) to Str, and calls Str.substr-rw with the arguments.
sub ords(Str(Cool) $str)
method ords()
Coerces the invocant (or in the sub form, the first argument) to Str, and returns a list of Unicode codepoints for each character.
say "Camelia".ords; # OUTPUT: «67 97 109 101 108 105 97»
say ords 10; # OUTPUT: «49 48»
This is the list-returning version of ord. The inverse operation in chrs. If you are only interested in the number of codepoints, codes is a possibly faster option.
sub chrs(*@codepoints --> Str:D)
method chrs()
Coerces the invocant (or in the sub form, the argument list) to a list of integers, and returns the string created by interpreting each integer as a Unicode codepoint, and joining the characters.
say <67 97 109 101 108 105 97>.chrs; # OUTPUT: «Camelia»
This is the list-input version of chr. The inverse operation is ords.
multi split( Str:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi split(Regex:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi split(@delimiters, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split( Str:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split(Regex:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split(@delimiters, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
the comb routine is a much better choice for many tasks that in other languages are handled by the split.">[ 1 ]
Coerces the invocant (or in the sub form, the second argument) to Str, splits it into pieces based on delimiters found in the string and returns the result as a Seq.
If $delimiter is a string, it is searched for literally and not treated as a regex. You can also provide multiple delimiters by specifying them as a list, which can mix Cool and Regex objects.
say split(';', "a;b;c").raku; # OUTPUT: «("a", "b", "c").Seq»
say split(';', "a;b;c", 2).raku; # OUTPUT: «("a", "b;c").Seq»
say split(';', "a;b;c,d").raku; # OUTPUT: «("a", "b", "c,d").Seq»
say split(/\;/, "a;b;c,d").raku; # OUTPUT: «("a", "b", "c,d").Seq»
say split(/<[;,]>/, "a;b;c,d").raku; # OUTPUT: «("a", "b", "c", "d").Seq»
say split(['a', /b+/, 4], '1a2bb345').raku; # OUTPUT: «("1", "2", "3", "5").Seq»
By default, split omits the matches, and returns a list of only those parts of the string that did not match. Specifying one of the :k, :v, :kv, :p adverbs changes that. Think of the matches as a list that is interleaved with the non-matching parts.
The :v interleaves the values of that list, which will be either Match objects, if a Regex was used as a matcher in the split, or Str objects, if a Cool was used as matcher. If multiple delimiters are specified, Match objects will be generated for all of them, unless all of the delimiters are Cool.
say 'abc'.split(/b/, :v); # OUTPUT: «(a ｢b｣ c)»
say 'abc'.split('b', :v); # OUTPUT: «(a b c)»
:k interleaves the keys, that is, the indexes:
say 'abc'.split(/b/, :k); # OUTPUT: «(a 0 c)»
:kv adds both indexes and matches:
say 'abc'.split(/b/, :kv); # OUTPUT: «(a 0 ｢b｣ c)»
and :p adds them as Pairs, using the same types for values as :v does:
say 'abc'.split(/b/, :p); # OUTPUT: «(a 0 => ｢b｣ c)»
say 'abc'.split('b', :p); # OUTPUT: «(a 0 => b c)»
You can only use one of the :k, :v, :kv, :p adverbs in a single call to split.
Note that empty chunks are not removed from the result list. For that behavior, use the :skip-empty named argument:
say ("f,,b,c,d".split: /","/ ).raku; # OUTPUT: «("f", "", "b", "c", "d").Seq»
say ("f,,b,c,d".split: /","/, :skip-empty).raku; # OUTPUT: «("f", "b", "c", "d").Seq»
sub lines(Str(Cool))
method lines()
Coerces the invocant (and in sub form, the argument) to Str, decomposes it into lines (with the newline characters stripped), and returns the list of lines.
say lines("a\nb\n").join('|'); # OUTPUT: «a|b»
say "some\nmore\nlines".lines.elems; # OUTPUT: «3»
This method can be used as part of an IO::Path to process a file line-by-line, since IO::Path objects inherit from Cool, e.g.:
for 'huge-csv'.IO.lines -> $line {
# Do something with $line
}
# or if you'll be processing later
my @lines = 'huge-csv'.IO.lines;
Without any arguments, sub lines operates on $*ARGFILES.
To modify values in place use is copy to force a writable container.
for $*IN.lines -> $_ is copy { s/(\w+)/{$0 ~ $0}/; .say }
method words(Cool:D: |c)
Coerces the invocant (or first argument, if it is called as a subroutine) to Str, and returns a list of words that make up the string. Check Str.words for additional arguments and its meaning.
say <The quick brown fox>.words.join('|'); # OUTPUT: «The|quick|brown|fox»
say <The quick brown fox>.words(2).join('|'); # OUTPUT: «The|quick»
Cool is the base class for many other classes, and some of them, like Match, can be converted to a string. This is what happens in this case:
say ( "easy come, easy goes" ~~ m:g/(ea\w+)/).words(Inf);
# OUTPUT: «(easy easy)»
say words( "easy come, easy goes" ~~ m:g/(ea\w+)/ , ∞);
# OUTPUT: «(easy easy)»
The example above illustrates two of the ways words can be invoked, with the first argument turned into invocant by its signature. Inf is the default value of the second argument, so in both cases (and forms) it can be simply omitted.
Only whitespace (including no-break space) counts as word boundaries
say <Flying on a Boeing 747>.words.join('|'); # OUTPUT: «Flying|on|a|Boeing|747»
In this case, "Boeing 747" includes a (visible only in the source) no-break space; words still splits the (resulting) Str on it, even if the original array only had 4 elements:
say <Flying on a Boeing 747>.join('|'); # OUTPUT: «Flying|on|a|Boeing 747»
Please see Str.words for more examples and ways to invoke it.
multi comb(Regex $matcher, Cool $input, $limit = *)
multi comb(Str $matcher, Cool $input, $limit = *)
multi comb(Int:D $size, Cool $input, $limit = *)
multi method comb(|c)
Returns a Seq of all (or if supplied, at most $limit) matches of the invocant (method form) or the second argument (sub form) against the Regex, string or defined number.
say "6 or 12".comb(/\d+/).join(", "); # OUTPUT: «6, 12»
say comb(/\d <[1..9]> /,(11..30)).join("--");
# OUTPUT:
# «11--12--13--14--15--16--17--18--19--21--22--23--24--25--26--27--28--29»
The second statement exemplifies the first form of comb, with a Regex that excludes multiples of ten, and a Range (which is Cool) as $input. comb stringifies the Range before applying .comb on the resulting string. Check Str.comb for its effect on different kind of input strings. When the first argument is an integer, it indicates the (maximum) size of the chunks the input is going to be divided in
say comb(3,[3,33,333,3333]).join("*"); # OUTPUT: «3 3*3 3*33 *333*3»
In this case the input is a list, which after transformation to Str (which includes the spaces) is divided in chunks of size 3.
method contains(Cool:D: |c)
Coerces the invocant to a Str, and calls Str.contains on it. Please refer to that version of the method for arguments and general syntax.
say 123.contains("2")# OUTPUT: «True»
Since Int is a subclass of Cool, 123 is coerced to a Str and then contains is called on it.
say (1,1, * + * … * > 250).contains(233)# OUTPUT: «True»
Seqs are also subclasses of Cool, and they are stringified to a comma-separated form. In this case we are also using an Int, which is going to be stringified also; "233" is included in that sequence, so it returns True. Please note that this sequence is not lazy; the stringification of lazy sequences does not include each and every one of their components for obvious reasons.
multi index(Cool:D $s, Cool:D $needle, :i(:$ignorecase), :m(:$ignoremark) --> Int:D)
multi index(Cool:D $s, Cool:D $needle, Cool:D $pos, :i(:$ignorecase), :m(:$ignoremark) --> Int:D)
multi method index(Cool:D: Cool:D $needle --> Int:D)
multi method index(Cool:D: Cool:D $needle, :m(:$ignoremark)! --> Int:D)
multi method index(Cool:D: Cool:D $needle, :i(:$ignorecase)!, :m(:$ignoremark) --> Int:D)
multi method index(Cool:D: Cool:D $needle, Cool:D $pos --> Int:D)
multi method index(Cool:D: Cool:D $needle, Cool:D $pos, :m(:$ignoremark)! --> Int:D)
multi method index(Cool:D: Cool:D $needle, Cool:D $pos, :i(:$ignorecase)!, :m(:$ignoremark) --> Int:D)
Coerces the first two arguments (in method form, also counting the invocant) to a Str, and searches for $needle in the string $s starting from $pos. It returns the offset into the string where $needle was found, and Nil if it was not found.
See the documentation in type Str for examples.
multi rindex(Cool:D $s, Cool:D $needle --> Int:D)
multi rindex(Cool:D $s, Cool:D $needle, Cool:D $pos --> Int:D)
multi method rindex(Cool:D: Cool:D $needle --> Int:D)
multi method rindex(Cool:D: Cool:D $needle, Cool:D $pos --> Int:D)
Coerces the first two arguments (including the invocant in method form) to Str and $pos to Int, and returns the last position of $needle in the string not after $pos. Returns Nil if $needle wasn't found.
See the documentation in type Str for examples.
method match(Cool:D: $target, *%adverbs)
Coerces the invocant to Stringy and calls the method match on it.
multi roots(Numeric(Cool) $x, Int(Cool) $n)
multi method roots(Int(Cool) $n)
Coerces the first argument (and in method form, the invocant) to Numeric and the second ($n) to Int, and produces a list of $n Complex $n-roots, which means numbers that, raised to the $nth power, approximately produce the original number.
For example
my $original = 16;
my @roots = $original.roots(4);
say @roots;
for @roots -> $r {
say abs($r ** 4 - $original);
}
# OUTPUT:«2+0i 1.22464679914735e-16+2i -2+2.44929359829471e-16i -3.67394039744206e-16-2i»
# OUTPUT:«1.77635683940025e-15»
# OUTPUT:«4.30267170434156e-15»
# OUTPUT:«8.03651692704705e-15»
# OUTPUT:«1.04441561648202e-14»
method subst(|)
Coerces the invocant to Stringy and calls Str.subst.
method trans(|)
Coerces the invocant to Str and calls Str.trans
method IO(--> IO::Path:D)
Coerces the invocant to IO::Path.
.say for '.'.IO.dir; # gives a directory listing
method sprintf(*@args)
Returns a string according to a series of format directives that are common in many languages; the object will be the format string, while the supplied arguments will be what's going to be formatted according to it.
"% 6s".sprintf('Þor').say; # OUTPUT: « Þor»
method printf(*@args)
Uses the object, as long as it is a format string, to format and print the arguments
"%.8f".printf(now - now ); # OUTPUT: «-0.00004118»
multi method Complex()
Coerces the invocant to a Numeric and calls its .Complex method. Fails if the coercion to a Numeric cannot be done.
say 1+1i.Complex; # OUTPUT: «1+1i»
say π.Complex; # OUTPUT: «3.141592653589793+0i»
say <1.3>.Complex; # OUTPUT: «1.3+0i»
say (-4/3).Complex; # OUTPUT: «-1.3333333333333333+0i»
say "foo".Complex.^name; # OUTPUT: «Failure»
multi method FatRat()
Coerces the invocant to a Numeric and calls its .FatRat method. Fails if the coercion to a Numeric cannot be done.
say 1+0i.FatRat; # OUTPUT: «1»
say 2e1.FatRat; # OUTPUT: «20»
say 1.3.FatRat; # OUTPUT: «1.3»
say (-4/3).FatRat; # OUTPUT: «-1.333333»
say "foo".FatRat.^name; # OUTPUT: «Failure»
multi method Int()
Coerces the invocant to a Numeric and calls its .Int method. Fails if the coercion to a Numeric cannot be done.
say 1+0i.Int; # OUTPUT: «1»
say <2e1>.Int; # OUTPUT: «20»
say 1.3.Int; # OUTPUT: «1»
say (-4/3).Int; # OUTPUT: «-1»
say "foo".Int.^name; # OUTPUT: «Failure»
multi method Num()
Coerces the invocant to a Numeric and calls its .Num method. Fails if the coercion to a Numeric cannot be done.
say 1+0i.Num; # OUTPUT: «1»
say 2e1.Num; # OUTPUT: «20»
say (16/9)².Num; # OUTPUT: «3.1604938271604937»
say (-4/3).Num; # OUTPUT: «-1.3333333333333333»
say "foo".Num.^name; # OUTPUT: «Failure»
multi method Rat()
Coerces the invocant to a Numeric and calls its .Rat method. Fails if the coercion to a Numeric cannot be done.
say 1+0i.Rat; # OUTPUT: «1»
say 2e1.Rat; # OUTPUT: «20»
say (-4/3).Rat; # OUTPUT: «-1.333333»
say "foo".Rat.^name; # OUTPUT: «Failure»
say (.numerator, .denominator) for π.Rat; # OUTPUT: «(355 113)»
multi method Real()
Coerces the invocant to a Numeric and calls its .Real method. Fails if the coercion to a Numeric cannot be done.
say 1+0i.Real; # OUTPUT: «1»
say 2e1.Real; # OUTPUT: «20»
say 1.3.Real; # OUTPUT: «1.3»
say (-4/3).Real; # OUTPUT: «-1.333333»
say "foo".Real.^name; # OUTPUT: «Failure»
multi method UInt()
Coerces the invocant to an Int. Fails if the coercion to an Int cannot be done or if the Int the invocant had been coerced to is negative.
say 1+0i.UInt; # OUTPUT: «1»
say 2e1.UInt; # OUTPUT: «20»
say 1.3.UInt; # OUTPUT: «1»
say (-4/3).UInt.^name; # OUTPUT: «Failure»
say "foo".UInt.^name; # OUTPUT: «Failure»
method uniparse(Cool:D: --> Str:D)
Available as of the 2021.04 release of the Rakudo compiler.
Coerces the invocant to a Str and then calls the uniparse on that. This mostly only makes sense for Match objects.
method Order(Cool:D: --> Order:D)
Available as of the 2022.02 release of the Rakudo compiler.
Coerces the invocant to an Int, and then returns one of the Order enums: Less if negative, Same if 0, More if positive.
method Failure(Cool:D: --> Failure:D)
Available as of the 2022.06 release of the Rakudo compiler.
Creates an X::AdHoc exception with the stringification of the invocant, and coerces that into a Failure object. Mainly intended to reduce the bytecode for error branches in code, to increase the chances of hot code getting inlined.